Beziehungen aus Tabelle erstellen

Sprache / Programm: Access ab Version 97

Beschreibung

Das Programm erstellt Beziehungen, die vom Programm 'BeziehungenLöschen' in einer Tabelle hinterlegt wurden.

VBA-Quelltext

Public Sub BeziehungenErstellen(NameTabelle As String)
Dim NeueBeziehung As DAO.Relation, Feld As Field
Dim BeziehungsNr As Integer, BeziehungsTabelle As DAO.Recordset

' Existiert die Tabelle ?
If Not RecordSetExistiert(NameTabelle) Then
MsgBox "Tabelle '" & NameTabelle & "' existiert nicht.", , "Beziehungen erstellen"
Exit Sub
End If

Set BeziehungsTabelle = CurrentDb.OpenRecordset("SELECT * FROM [" & NameTabelle & "] ORDER BY [BeziehungsNr];")
BeziehungsTabelle.MoveFirst
While Not BeziehungsTabelle.EOF
BeziehungsNr = BeziehungsTabelle![BeziehungsNr]
Set NeueBeziehung = CurrentDb.CreateRelation(BeziehungsTabelle!NAme, BeziehungsTabelle!Table, BeziehungsTabelle!ForeignTable, BeziehungsTabelle!Attributes)
NeueBeziehung.PartialReplica = BeziehungsTabelle!PartialReplica
Do
Set Feld = NeueBeziehung.CreateField(BeziehungsTabelle!FieldName)
Feld.ForeignName = BeziehungsTabelle!ForeignFieldName
NeueBeziehung.Fields.Append Feld
BeziehungsTabelle.MoveNext
If BeziehungsTabelle.EOF Then Exit Do
Loop While BeziehungsNr = BeziehungsTabelle![BeziehungsNr]
CurrentDb.Relations.Append NeueBeziehung
Wend

End Sub

Argumente der Funktion/Prozedur

NameTabelle

Name der Tabelle mit den Informationen zu den Beziehungen

Hinweis

Um die Beziehungen in einer Tabelle zu speichern, kann die Funktion BeziehungenLöschen verwendet werden.

Anwendungsgebiete, Fehler und Warnungen

Verwendet die DAO Objektbibliothek. Ab Access 2000 muss diese explizit im VBA-Editor über 'Extras' -> 'Verweise' als 'Microsoft DAO 3.6' (oder höher) eingebunden werden und vor die 'Microsoft ADO 2.1' (oder höher) Bibliothek gesetzt werden.